/Globals
globals
     gamecache cache = InitGameCache("map")
     real timeout = 30//Timeout for ressurect
     real array UXS
     real array UYS
endglobals
//RB
function U2I takes unit u returns integer
     return u
     return 0
endfunction

function I2U takes integer i returns unit
     return i
     return null
endfunction
//Resurrect system
function OnDie takes nothing returns nothing
     local unit u = GetDyingUnit()
     local integer id = GetUnitTypeId(u)
     local integer i = U2I(u)
     local integer nmb = GetStoredInteger(cache, "nmbs", I2S(i))
     call FlushStoredInteger(cache, "nmbs", I2S(i))
     call TriggerSleepAction(timeout)
     call RemoveUnit(u)
     set u = CreateUnit(Player(12), id, UXS[nmb], UYS[nmb], 0)
     call StoreInteger(cache, "nmbs", I2S(U2I(u)), nmb)
     set u = null
endfunction

function Res_Init takes nothing returns nothing
     local group g = CreateGroup()
     local unit u
     local integer i = 1
     local trigger t = CreateTrigger()
     call GroupEnumUnitsOfPlayer(g, Player(12), null)
     loop
         set u = FirstOfGroup(g)
         exitwhen u == null or i >= 8000
         set UXS[i] = GetUnitX(u)
         set UYS[i] = GetUnitY(u)
         call StoreInteger(cache, "nmbs", I2S(U2I(u)), i)
         call GroupRemoveUnit(g, u)
         set i = i + 1
     endloop
     call DestroyGroup(g)
     call TriggerRegisterPlayerUnitEvent(t, Player(12), EVENT_PLAYER_UNIT_DEATH, null)
     call TriggerAddAction(t, function OnDie)
     set t = null
endfunction