globals
      gamecache Cache = InitGameCache("TEW.w3v")
      group MG = CreateGroup()
endglobals
//=================================================================================
//=                    Return Bug                    =
//=================================================================================
function GetUnitId takes unit u returns integer
      return u
      return 0
endfunction
function GetUnit takes integer i returns unit
      return i
      return null
endfunction
//=================================================================================
//=                    End                    =
//=================================================================================
//=================================================================================
//=                    Store System                    =
//=================================================================================
function StoreUnitReal takes unit u, real r, string c returns nothing
      local string s = I2S(GetUnitId(u))
      call StoreReal(Cache, s, c, r)
endfunction
//Stores unit real
function GetUnitReal takes unit u, string c returns real
      local string s = I2S(GetUnitId(u))
      return GetStoredReal(Cache, s, c)
endfunction
//Returns unit real
//=================================================================================
//=                    End                    =
//=================================================================================
//=================================================================================
//=                    Projectle system                    =
//=================================================================================
function ChangeUnitX takes unit u, real x, real ang, real r returns nothing
      call SetUnitX(u, x + Cos(ang) * r)
endfunction
//Changes unit x
function ChangeUnitY takes unit u, real y, real ang, real r returns nothing
      call SetUnitY(u, y + Sin(ang) * r)
endfunction
//Changes unit y
function Move takes nothing returns nothing
      local unit u = GetEnumUnit()
      local real r = GetUnitReal(u, "MoveSpeed")
      local real range = GetUnitReal(u, "MoveRange")
      local real ang = GetUnitReal(u, "MoveAngle")
      local real x = GetUnitX(u)
      local real y = GetUnitY(u)
      set range = range - r
      call StoreUnitReal(u, range, "MoveRange")
      call ChangeUnitX(u, x, ang, r)
      call ChangeUnitY(u, y, ang, r)
      if range <= 0 then
          call GroupRemoveUnit(MG, u)
      endif      
endfunction
function LineMove takes nothing returns nothing
      call ForGroup(MG, function Move)
endfunction
function StartLineMove takes unit u, real r, real speed, real ang returns nothing
      local real range = GetUnitReal(u, "MoveRange")
      call GroupAddUnit(MG, u)
      set range = range + r
      call StoreUnitReal(u, range, "MoveRange")
      call StoreUnitReal(u, speed, "MoveSpeed")
      call StoreUnitReal(u, ang, "MoveAngle")
endfunction
//=================================================================================
//=                    End                    =
//=================================================================================