function Trig_Essence_Shift_Timer takes nothing returns nothing  
      local timer ta=GetExpiredTimer()  
      local integer i=GetHandleId(ta)  
      local unit t=LoadUnitHandle(udg_Hash,i,1)  
      local unit u=LoadUnitHandle(udg_Hash,i,0)  
      call SetHeroStr(t,GetHeroStr(t,true)+1,true)  
      call SetHeroAgi(t,GetHeroAgi(t,true)+2,true)  
      call SetHeroInt(t,GetHeroInt(t,true)+1,true)  
      call SetHeroAgi(u,GetHeroAgi(u,true)-2,true)  
      call SetHeroStr(u,GetHeroStr(u,true)-1,true)  
      call SetHeroInt(u,GetHeroInt(u,true)-1,true)  
      call PauseTimer(ta)  
      call DestroyTimer(ta)  
      call FlushChildHashtable(udg_Hash,i)  
      set t=null  
      set u=null  
      set ta=null  
endfunction  

function Trig_Essence_Shift_Actions takes nothing returns nothing  
      local unit u=GetAttacker()  
      local unit t=GetTriggerUnit()  
      local timer ta  
      local integer i  
      if  GetUnitAbilityLevel(u, 'A004') > 0  and  IsUnitType(t, UNIT_TYPE_HERO) == true  then  
          set ta=CreateTimer()  
          set i=GetHandleId(ta)  
          call SetHeroStr(u,GetHeroStr(u,true)+1,true)  
          call SetHeroAgi(u,GetHeroAgi(u,true)+2,true)  
          call SetHeroInt(u,GetHeroInt(u,true)+1,true)  
          call SetHeroAgi(t,GetHeroAgi(t,true)-2,true)  
          call SetHeroStr(t,GetHeroStr(t,true)-1,true)  
          call SetHeroInt(t,GetHeroInt(t,true)-1,true)  
          call SaveUnitHandle(udg_Hash,i,0,u)  
          call SaveUnitHandle(udg_Hash,i,1,t)  
          call TimerStart(ta,15.00*I2R(GetUnitAbilityLevel(u,'A004')), false, function Trig_Essence_Shift_Timer)  
      endif  
      set ta=null  
      set u=null  
      set t=null  
endfunction  

//===========================================================================  
function InitTrig_Essence_Shift_JASS takes nothing returns nothing  
      local integer index=0  
      local trigger trig=CreateTrigger()  
      loop  
          call TriggerRegisterPlayerUnitEvent(trig,Player(index),EVENT_PLAYER_UNIT_ATTACKED,null)  
          set index=index+1  
          exitwhen index==bj_MAX_PLAYER_SLOTS  
      endloop  
      call TriggerAddAction(trig,function Trig_Essence_Shift_Actions)  
      set trig=null  
endfunction